;; org.elより
(defcustom org-latex-to-html-convert-command nil
  "Shell command to convert LaTeX fragments to HTML.
This command is very open-ended: the output of the command will
directly replace the LaTeX fragment in the resulting HTML.
Replace format-specifiers in the command as noted below and use
`shell-command' to convert LaTeX to HTML.
%i:     The LaTeX fragment to be converted (shell-escaped).
        It must not be used inside a quoted argument, the result of %i
        expansion inside a quoted argument is undefined.

For example, this could be used with LaTeXML as
\"latexmlc literal:%i --profile=math --preload=siunitx.sty 2>/dev/null\"."
  :group 'org-latex
  :package-version '(Org . "9.7")
  :type '(choice
          (const :tag "None" nil)
          (string :tag "Shell command")))

(setq org-html-with-latex 'html)

;; 設定上は`mathjax'にすることによってlatex-environmentでも変換処理をさせる。
;; `org-html-latex-environment'はなぜか`html'を認識しない。
;; `org-html-latex-fragment'は認識する。
(setq org-html-with-latex 'mathjax)

;; mathjax用のHTMLヘッダー(JavaScript)は必要ない。
(setq org-html-mathjax-template "")

;; processing-typeが`mathjax'のときは`html'に書き替えることで
;; `org-format-latex-as-html'関数を無理矢理呼ばせる。
;; 経路:
;; org-html-latex-{environment|fragment}
;;   => `org-html-format-latex'
;;     => `org-format-latex'
;;       => `org-format-latex-as-html'
(defun my-org-format-latex:around (old-fun
                                   prefix &optional beg end dir overlays msg
                                   forbuffer processing-type)
  (funcall old-fun prefix beg end dir overlays msg forbuffer
           (if (eq processing-type 'mathjax)
               'html
             processing-type)))
(advice-add #'org-format-latex :around #'my-org-format-latex:around)
;; (advice-remove 'org-format-latex 'my-org-format-latex:around)

;; `org-format-latex-as-html'をpandoc用のものに置き換える。
(defun my-org-format-latex-as-html (latex-fragment)
  "Convert LATEX-FRAGMENT to HTML."
  (let* ((cmd "pandoc --mathml -f latex")
         (html
          ;; 引数で渡すと問題が起きがちなので標準入力で渡す。
          (with-temp-buffer
            (insert latex-fragment)
            (let ((coding-system-for-read 'utf-8)
                  (coding-system-for-write 'utf-8)) ;; 私の環境だと文字化け防止に必要
              (message "Running %s" cmd)
              (shell-command-on-region (point-min) (point-max) cmd nil t))
            (buffer-string))))
    ;; <p>と</p>\nを除去
    ;; (pandocの変換結果は<p>タグで囲まれている。
    ;;  texmathを使えば囲まないように出来るらしい。
    ;;  参考: https://news.ycombinator.com/item?id=43883052)
    (if (string-match "\\`<p>\\(.*\\)</p>[\n\r ]*\\'" html)
        (match-string 1 html)
      ;; マッチしない。pandocの仕様が変わった？
      html)))
(advice-add #'org-format-latex-as-html :override #'my-org-format-latex-as-html)
;; (advice-remove #'org-format-latex-as-html #'my-org-format-latex-as-html)

これは $x^2$ です(~$ .. $~ を使用)。

これは \( x^2 \) です(~\( .. \)~ を使用)。

これは $$ x^2 $$ です(~$$ .. $$~ を使用)。

これは \[x^2\] です(~\[ .. \]~ を使用)。

\begin{equation}
x^2 + y^2 = r^2
\end{equation}

\begin{gather}
 (a+b)^2 = a^2 + 2ab + b^2           \\
 (a-b)^2 = a^2 - 2ab + b^2           \\
 (a+b)^3 = a^3 + 3a^2b + 3ab^2 + b^3 
\end{gather}

(defun calcFunc-orgref (refspec)
  (save-current-buffer ;; 現在のバッファを保存・脱出時に復元
    ;; 式が埋め込まれているバッファを選択
    ;; (呼び出し時点では *Calculator* バッファが選択されているので)
    (calc-embedded-original-buffer t calc-embedded-info)

    (my-calc-value-from-elisp ;; Calc用の値へ変換
     (org-babel-ref-resolve ;; 参照を解決
      ;; Calcの式REFSPECを文字列へ変換する
      (my-calc-expr-to-string refspec)))))

(defun my-calc-expr-to-string (expr)
  "Calcの式を文字列へ変換します。"
  (pcase expr
    ;; ベクトル "table-1"
    (`(vec . ,elements)
     (apply #'string elements))
    ;; 変数 table1 or table#1
    (`(var ,dname ,vsym)
     (if (seq-contains-p (symbol-name dname) ?#)
         ;; 表示名に#が入っていたら変数名シンボルの方を使う
         (symbol-name vsym)
       (symbol-name dname)))
    ;; TODO: (calcFunc-subscr (var <name> var-<name>) ???)みたいなのも無理矢理 <name>_??? にする？ (???の部分は数だったり変数だったりすると思う)
    (_ (error "Cannot convert to string from %s" expr))))

(defun my-calc-value-from-elisp (value)
  "Emacs Lispの値をCalcの値へ変換します。"
  (cond
   ;; 整数はそのまま
   ((integerp value) value)
   ;; 浮動小数点数は……良い方法が分からない。
   ;; とりあえず文字列化してから読み込んでみる。
   ((floatp value) (math-read-number (number-to-string value)))
   ;; 文字列は整数のベクトルへ
   ((stringp value) (cons 'vec (string-to-list value)))
   ;; リストはベクトルへ(要素は再帰的に変換)
   ((listp value)
    (cons 'vec (mapcar #'my-calc-value-from-elisp value)))
   ;; その他の型はとりあえずそのまま返してみる
   (t value)))

# ■テーブルを参照する例

#+NAME: fruits
| Name   | Quantity |
|--------+----------|
| Apple  |       15 |
| Orange |       24 |
| Banana |        3 |
|--------+----------|
|        |       42 |
#+TBLFM: @>$2=vsum(@I..@II)

りんごは{{{calc(orgref(fruits)_3_2 => 15)}}}個、オレンジは{{{calc(orgref(fruits)_4_2 => 24)}}}個、バナナは{{{calc(orgref(fruits)_5_2 => 3)}}}、合計{{{calc(subvec(orgref(fruits), -1)_1_2 => 42)}}}個の果物があります。

# ■リストを参照する例

#+NAME: list-ex1
- 10
- 20
  - 22 (←無視される)
  - 24 (←無視される)
- 30

リストを参照すると $orgref(list#ex1) => [10, 20, 30]$ のようになります。(注意:マクロを使うと , がマクロの引数区切りになるので [10 までしかエクスポートされない！)

# ■コードブロック(と上のリスト)を参照する例

#+name: list-sum
#+begin_src elisp :var lst=list-ex1
(apply #'+ lst)
#+end_src

リストの値の合計: {{{calc(orgref(list#sum) => 60)}}}

1～4を足すと $1+2+3+4$ になります。

1～4を足すと $10$ になります。

$1+2+3+4=>$

$1 + 2 + 3 + 4 => 10$

$x:=256$

$x^2=>$

$x^2 => 65536$

;; マクロ {{{calc(式)}}} を定義する
;;   {{{calc(左辺=>結果)}}}       => 結果のみエクスポート
;;   {{{calc(変数:=右辺=>結果)}}} => 結果のみエクスポート
;;   {{{calc(変数:=右辺)}}}       => 右辺のみ (空にして => を必須にしても良いが)
;;   {{{calc(式)}}}               => 式のみ (評価結果にしても良いが)
(defun my-org-macro-calc (expr)
  (cond
   ((string-match "=> *" expr) ;; Include x := y + 3 => 20
    (substring expr (match-end 0)))
   ((string-match ":= *" expr)
    (substring expr (match-end 0)))
   (t expr)))

(setf (alist-get "calc" org-export-global-macros nil nil #'equal)
      "(eval (my-org-macro-calc $1))")

;; org-modeでのCalc式の区切りパターンを追加。
;; 新しいマクロ表記({{{calc()}}})の他に$や\[等の従来のものも一応残す。
(setf (alist-get 'org-mode calc-embedded-open-close-formula-alist)
      (list (concat
             "\\`\\|^\n\\|\\$\\$?\\|\\\\\\[\\|^\\\\begin[^{].*\n\\|^\\\\begin{.*[^x]}.*\n\\|\\\\("
             "\\|{{{[a-zA-Z][-a-zA-Z0-9_]*(" ;;マクロ
             "\\|\\<src_[^ \t\n[{]+\\(\\[[^]]*\\]\\)?{" ;;インラインソース
             "\\|^#\\+begin[_:][^\n]*\n" ;;ブロック
             "\\|[[:nonascii:]]:? ?" ;;ASCII以外(お好みで)
             )
            (concat
             "\\'\\|\n$\\|\\$\\$?\\|\\\\]\\|^\\\\end[^{].*\n\\|^\\\\end{.*[^x]}.*\n\\|\\\\)"
             "\\|)}}}" ;;マクロ
             "\\|}" ;;インラインソース
             "\\|^#\\+end[_:][^\n]*\n" ;;ブロック
             "\\| ?[[:nonascii:]]"
             )))
;; C-x * a (`calc-embedded-activate')で検索するパターンを追加
;; 設定しなくても := や => は検索するので必要なのかどうか分からないが一応
(setf (alist-get 'org-mode calc-embedded-announce-formula-alist)
      (concat
       "# Embed\n\\(# .*\n\\)*\\|"
       "{{{calc(.*?)}}}"))
;; d p (`calc-show-plain')を使ったときに出力されるコメントの構文
;; 一応他のメジャーモードの時と同じように設定しておく
(setf (alist-get 'org-mode calc-embedded-open-close-plain-alist)
      '("# %% " " %%\n"))
;; C-x * f (`calc-embedded-new-formula') で数式を作るときに挿入する区切り
;; 設定しない方がいい？　余計かも
(setf (alist-get 'org-mode calc-embedded-open-close-new-formula-alist)
      '("{{{calc(" ")}}}"))

# 杯数: $ servings := 3 $

# [calc-mode: float-format: (fix 3)]
{{{calc(servings => 3)}}}杯分を作るには、水を{{{calc(water := 250 servings => 750 )}}}ml、レモン果汁を{{{calc(lemon := 125 servings => 375)}}}ml使います。合わせると{{{calc(water + lemon => 1125)}}}mlとなり、果汁{{{calc(100 lemon / (lemon + water) => 33.333)}}}%のレモン水になります。

2025年10月1日の為替レートはrate_before := 148.170円/ドルだった。10月10日はrate_after := 153.090円/ドル。実に100 (rate_after / rate_before - 1) => 3.320パーセント上がったことになる。

1～4を足すと src_calc[:eval no-export]{1+2+3+4} {{{results(=10=)}}} になります。

1～4を足すと src_calc[:eval no-export :wrap t]{1+2+3+4} {{{results(10)}}}になります。

1～4を足す式は src_calc[:exports code]{1+2+3+4} と書きます。

#+NAME: drink-params
| servings |   3 |
| water    | 750 |
| lemon    | 375 |
#+TBLFM: @2$2=250*@1$2::@3$2=125*@1$2

src_calc[:eval no-export :wrap t :var params=drink-params]{params_1_2} {{{results(3)}}}杯分を作るには、水を src_calc[:eval no-export :wrap t :var params=drink-params]{params_2_2} {{{results(750)}}}ml、レモン果汁を src_calc[:eval no-export :wrap t :var params=drink-params]{params_3_2} {{{results(375)}}}ml使います。合わせると src_calc[:eval no-export :wrap t :var params=drink-params]{params_2_2+params_3_2} {{{results(1125)}}}mlとなり、果汁src_calc[:eval no-export :wrap t :var params=drink-params]{100 params_3_2/(params_2_2+params_3_2)} {{{results(33.333)}}}%のレモン水になります。

* プロパティを使う方法
:PROPERTIES:
:header-args:calc: :eval no-export :wrap t :var servings=3 :var water=250 :var lemon=125
:END:

src_calc{servings} {{{results(3)}}}杯分を作るには、水を src_calc{servings water} {{{results(750)}}}ml、レモン果汁を src_calc{servings lemon} {{{results(375)}}}ml使います。合わせると src_calc{servings*(water + lemon)} {{{results(1125)}}}mlとなり、果汁 src_calc{100 lemon/(water+lemon)} {{{results(33.3333333333)}}}%のレモン水になります。