Monthly Archives: 7月 2021

2021-07-27 Emacs

dired-details-rを修正する

皆さんは dired-dwim-target 変数を使ってますか？　diredでコピー先や移動先を良い感じに推測してくれる機能です。分割ウィンドウで他のディレクトリを開いているとコピー先や移動先をそのディレクトリにしてくれます。古からある二画面ファイラーなんかではおなじみの機能ですね。ついでにM-nで出る「未来の履歴」にもいくつか候補を設定しておいてくれます。(EmacsではM(Alt)-p(previousのp)で過去の履歴をたどれてM-n(next)で現在に戻ってこれますが、現在を越えてM-nを押すとこれから選びそうな候補が出てくるというUIの考え方が(一部で)あります)

それでコピーや移動のときには大変便利なのですが、ファイル名を変更するときにはよくミスを犯してしまうのです。なぜならファイル名の変更と移動は同じRキーに割り当てられているからです。名前の変更はファイルの移動と同じ、または逆にファイルの移動はディレクトリパスも含めた名前の変更と同じと考えられるからです。Unixではどちらもmvコマンドですし。それでファイル名を変更しようとRキーを押したとき、 dired-dwim-target が有効だとたまたま開いていた別のディレクトリが移動先として設定されてしまうわけです。それに気がつかずに新しいファイル名を入力してEnterを押すと、ファイル名も変わるのですが同時に別のディレクトリにファイルが飛んで行ってしまうわけです。ぎゃー！

というわけでどうにかならないのかなと。移動と名前の変更が同じキーになっているのが原因ですから、別のキーに割り当てて候補の出方を変えるというのも手です。小文字のrは使っていないのでここに「ファイル名変更(ディレクトリ変更不可)」を割り当てるとか。でも非標準の操作体系を増やすと別のマシンを使うときに戸惑うのであまりやりたくありません(いまさら！)。安全優先でRは名前変更のための候補を優先して出し、移動先の候補はM-nで出すだけで十分かもしれません。と、Twitterでつぶやいたのですが……

名前変更には wdired 使ってますhttps://t.co/y1GnMtOuAj https://t.co/ER3sWOqS6Y

— iquiw (@iquiw) July 26, 2021

「名前変更には wdired 使ってます」との天の声が。

なんとそんな使い分けの方法があったとは！

wdiredとはファイル一覧のファイル名部分をテキストエディタの要領で編集するとファイル名が変わってくれるという便利機能です。

しかし私がwdiredを使っていないのには理由がありまして、以前wdiredを試したときにファイル名の入力がうまくいかなかったり、うまく行っても表示がおかしくなったりしたのです。

というのも私はdired-details-rというファイルサイズやタイムスタンプなどの詳細をファイル名の右に出す拡張を作っていて、どうもそれが悪さをしているようなのです。

しかしそれを直してしまえばwdiredを使ってみるのもやぶさかではありません。

というわけで重い腰を上げて dired-details-r を直すことにしました。他にも色々直したいところがあったのでついでに直すことにしました。

wdiredでファイル名を編集したときにファイル名の先頭でread-onlyエラーで書き替えられないことがあったり、書き替えられても書き替えた部分が表示されないことがある不具合を修正
ファイル名の末尾にカーソル(ポイント)を合わせられない不具合を修正(詳細情報の右に飛ぶ。wdiredでファイル名の末尾に文字を追加すると追加した部分だけ詳細情報の右に表示される！)
カスタマイズまわり(グループとか型とか)の修正
マイナーモード化(dired-details-r-mode)
一部のファイルだけ更新がかかったときに列が乱れる不具合の修正
"(" キーでの表示切り替えで元の表示形式(詳細の左表示)に戻せる機能を追加(wdiredでパーミッションを編集したい場合に備えて)
設定のデフォルト値の調整
導入方法の修正(以前はrequireするだけでしたが、マイナーモード化したので (dired-details-r-setup) を呼び出すか自分でマイナーモードを起動するか選択可能に)

以上を修正。

晴れてwdiredが正常に使えるようになりました。

wdiredでのファイル名変更手順は、C-x C-q で編集を開始し、ファイル名を書き替えてから C-c C-c または再度C-x C-q。Rを押してファイル名を書くより面倒かなと思ったのですが案外違和感がありません。C-x C-qはリードオンリーモードの切り替えでよく使うキー操作です。通常diredはリードオンリーモードになっていてテキストを書き替えられませんが、リードオンリーモードを解除してファイル名部分を書き替えて確定、または再度リードオンリーモードを有効にする、というある意味自然な流れなのは知っていました。しかしそうは言ってもタイプ数が増えるのだから面倒だろうと思ってもいたのですが、想像していたよりも違和感なく素早く操作できます。しばらく名前の変更はwdired縛りで行こうと思います。一括変更はさすがに % m でマークして % R で正規表現置換した方が楽な気もしますがどうでしょうね。

色々ときっかけを頂いたiquiwさんありがとうございました。

2021-07-24 Emacs, org-mode

月の満ち欠け画像をアジェンダに表示する

以前月の出、月の入り、月齢をorg-modeのアジェンダに表示する仕組みを作った(moonrise-el)のですが、その時に月の満ち欠けを画像で表示できたらなぁと思っていたのでした。

というのも Emacs で時の流れを感じる - Qiita という記事でモードラインに月の満ち欠けを表示しているのを見ていいなーと思っていたからです。

その記事で紹介しているコードではU+1F311からU+1F318にある絵文字を使用して月の満ち欠けを表現しているのですが、私の使っているEmacsではフォントの設定が十分ではなく絵文字が表示できないのでその方法は使えませんでした(Windowsではカラー絵文字が使えないというのもあります)。

最近all-the-iconsを導入したのですが、その中に入っていた Weather Icons というフォントに月の満ち欠けのグリフが入っているのを見つけました。

これを使うと次のようなコードで月の満ち欠けを表現できます。

(insert (all-the-icons-wicon "moon-14")) ;;0から27まで指定可能

これは使えると思い次のコードを作成しました。

(require 'all-the-icons)
(setq moonrise-moon-age-format
      (lambda (age)
        (concat (format "(%.2f) " age)
                 (all-the-icons-wicon
                  (format "moon-%d"
                          (mod (round (* (/ age 29.53) 28)) 28))
                  :v-adjust -0.1))))

本当は太陽と月の黄経差から求めた方が良いのですがmoonrise-elにはその機能が無いのでとりあえず月齢を使って計算しています。(2021-07-25追記:moonrise-elに月相を計算する機能を追加しました。現在は何も設定しなくても画像が出ます)

早速実行してみたのですが、org-modeのアジェンダでは正しいグリフが表示されません。calendarからL m(calendar-moonrise-moonset)やL d(calendar-moonrise-moonset-month)したときは正しく表示されます。

調べてみたところorg-agenda.el内でテキストプロパティfaceを'org-agenda-calendar-sexpに設定してしまうのが原因でした。all-the-iconsはテキストプロパティのfont-lock-faceにフォントファミリーを指定することで狙ったフォントでグリフを表示させるの仕組みなので、faceが指定されると違うフォントが選択されて正しいグリフで表示されなくなってしまいます。

困りました。このためだけにorg-agenda.elに手を入れるのは気が進みません。

何か良い方法は無いものか。describe-charでテキストプロパティの状態を眺めているとall-the-iconsが出力したfont-lock-faceプロパティ自体はバッファに反映されている点に気がつきました(faceプロパティが追加されたのでそちらが優先されているわけです)。つまり上の設定のlambda関数の中で生成したテキストプロパティ自体は正しくアジェンダバッファに反映されているわけです。テキストプロパティが使えるのなら画像を表示するのは簡単です。displayプロパティを使えば良いのです。

まず月の満ち欠けを表す画像を用意します。たまたまPCに入っていたBlenderでサクッと作ってみました。球と平行光源とカメラを置いて光源の向きをグルッと回すアニメーションを設定してレンダリングするだけです。

次に変数moonrise-moon-age-formatにはその画像を使うdisplayプロパティ付きの文字列を生成する関数を指定します。

(setq moonrise-moon-age-format
      (lambda (age)
        (concat (format "(%.2f) " age)
                (propertize
                 "A" 'display
                 (create-image
                  (format "~/tmp/moonphases/moonphase-%02d.png"
                          (min 30 (round (* (/ age 29.53) 30))))
                  nil nil
                  :ascent 'center)))))

すると狙い通りagendaバッファ上に月の満ち欠けが画像で表示されました。

無事目的は達成できたのですが画像ファイルを管理するのが面倒です。よく考えてみたらSVGが使えるのですからEmacs内で生成してしまえば良さそうなものです。球の光が当たる境目は三角関数で簡単に求められるでしょう。

(require 'svg)
(defun moonrise-create-moon-svg (age size)
  (let* ((svg (svg-create size size))
         ;; 円の中心と半径
         (cx (* 0.5 size))
         (cy (* 0.5 size))
         (radius (* 0.48 size))
         ;; 円の分割数
         (ndiv 32)
         (2pi/ndiv (* 2.0 (/ pi ndiv)))
         ;; 月齢をラジアンへ
         (age-rad (* 2.0 pi (/ (min (max age 0.0) 29.53) 29.53)))
         ;; 光が当たる部分の右側と左側の位置
         (right-edge (if (<= age-rad pi) 1.0 (- (cos age-rad))))
         (left-edge (if (>= age-rad pi) 1.0 (- (cos age-rad)))))
    ;; 光が当たっていない月の全球
    (svg-circle svg cx cy radius :fill "#000")
    ;; 光が当たっている部分
    (svg-polygon
     svg
     (cl-loop for i from 0 to ndiv
              collect (let ((i-rad (* i 2pi/ndiv))
                            (edge (if (< (* 2 i) ndiv) right-edge left-edge)))
                        (cons (+ cx (* (sin i-rad) radius edge))
                              (- cy (* (cos i-rad) radius)))))
     :fill "#ffc")
    (svg-image svg :ascent 'center)))

試しに画像をバッファに挿入してみると正しく表示されます。

(cl-loop for i from 0 to 28 do
         (insert-image (moonrise-create-moon-svg i 16)))

これを使う設定は次のようになります。

(setq moonrise-moon-age-format
      (lambda (age)
        (concat (format "(%.2f) " age)
                (propertize
                 "A" 'display
                 (moonrise-create-moon-svg age 16)))))

ちゃんと狙い通り表示されました。

Emacsでは、設定に文字列をフォーマットする関数を指定することが良くあると思います。そういった場所では今回と同様の手法でSVG画像を使える可能性があります(返した文字列のテキストプロパティがそのままバッファにinsertされていることが必要です)。他の用途でも応用が利くかもしれないなと思いましたので紹介してみました。

＃モードラインなんて全体をSVGで書いちゃえば良いんじゃないの？(テキストまわりの制御が難しいか？)

2021-07-23 Emacs

neotreeで(setq neo-smart-open t)すると固まる(Windows)

neotreeを試してみたのですが、neo-smart-openをtにするとf8に割り当てたneotree-toggleを押したときに固まることがありました。普通のファイルを開いているときは固まらず、scratchやdiredでディレクトリを開いているときに固まるようです。

コードを追ってみたところ neo-buffer--select-file-node 関数の中で無限ループに陥ってしまう場所を見つけました。

https://github.com/jaypei/emacs-neotree/blob/98fe21334affaffe2334bf7c987edaf1980d2d0b/neotree.el#L1632

親ディレクトリへ移動するループで、ルートに到達したかの判定を"/"と比較することで行っています。Windowsでは"c:/"等がルートで何度neo-path--updirを適用しても決して"/"になりませんからいつまで経っても終わりません。

とりあえず"/"を"c:/"にしたら直ったのですが、それではあんまりなのでupdirしたときにパスが変化しなかったら終わらせるようにしてみました。

うまくadviceもかけられないしneotree.el読み込み後に関数まるごと再定義。neotreeはそんなに頻繁に更新されていないみたいなのでまあいいか。

(with-eval-after-load "neotree"
  (defun neo-buffer--select-file-node (file &optional recursive-p)
    "Select the node that corresponds to the FILE.
If RECURSIVE-P is non nil, find files will recursively."
    (let ((efile file)
          (iter-prev-dir nil) ;;ADD
          (iter-curr-dir nil)
          (file-node-find-p nil)
          (file-node-list nil))
      (unless (file-name-absolute-p efile)
        (setq efile (expand-file-name efile)))
      (setq iter-curr-dir efile)
      (catch 'return
        (while t
          (setq iter-prev-dir iter-curr-dir) ;;ADD
          (setq iter-curr-dir (neo-path--updir iter-curr-dir))
          (push iter-curr-dir file-node-list)
          (when (neo-path--file-equal-p iter-curr-dir neo-buffer--start-node)
            (setq file-node-find-p t)
            (throw 'return nil))
          (let ((niter-curr-dir (file-remote-p iter-curr-dir 'localname)))
            (unless niter-curr-dir
              (setq niter-curr-dir iter-curr-dir))
            (when (or (string= iter-curr-dir iter-prev-dir) ;;ADD
                      (neo-path--file-equal-p niter-curr-dir "/"))
              (setq file-node-find-p nil)
              (throw 'return nil)))))
      (when file-node-find-p
        (dolist (p file-node-list)
          (neo-buffer--set-expand p t))
        (neo-buffer--save-cursor-pos file)
        (neo-buffer--refresh nil)))))