;; org-match-sparse-treeをベースに修正
(defun org-match-sparse-tree-show-subtree (&optional todo-only match)
  "Create a sparse tree according to tags string MATCH.

MATCH is a string with match syntax.  It can contain a selection
of tags (\"+work+urgent-boss\"), properties (\"LEVEL>3\"), and
TODO keywords (\"TODO=\\\"WAITING\\\"\") or a combination of
those.  See the manual for details.

If optional argument TODO-ONLY is non-nil, only select lines that
are also TODO tasks."
  (interactive "P")
  (org-agenda-prepare-buffers (list (current-buffer)))
  (let ((org--matcher-tags-todo-only todo-only))

    ;; 修正点ここから
    ;; まずはトップレベル以外は全て非表示にする。ハイライトももしあれば解除する。
    (org-overview)
    (org-remove-occur-highlights)
    ;; 修正点ここまで

    (org-scan-tags
     ;; 修正点ここから
     ;; マッチしたところをハイライトしてからサブツリーを表示する
     (lambda ()
       (and org-highlight-sparse-tree-matches
            (org-get-heading) (match-end 0)
            (org-highlight-new-match
             (match-beginning 1) (match-end 1)))

       (org-show-subtree) )
     ;; 修正点ここまで
     (cdr (org-make-tags-matcher match))
     org--matcher-tags-todo-only)))

(require 'cl)
(defun org-match-sparse-tree-show-subtree (&optional todo-only match)
  (interactive "P")
  (flet ((org-show-context (&optional key) (org-show-subtree)))
    (org-match-sparse-tree todo-only match)))

(defun org-show-occur-highlights-subtree ()
  (interactive)
  (save-excursion
    (goto-char (point-min))

    (while (ignore-errors (org-occur-next-match 1))
      (org-show-subtree))))

;; org-sparse-tree-cycle.el
;; https://misohena.jp/blog/2020-04-15-show-contents-of-entry-when-sparse-tree-in-org-mode.html
;;

(defun org-sparse-tree-show-all ()
  "マッチした部分をサブツリーを含めて表示します。"
  (interactive)
  (save-excursion
    (org-overview)

    (goto-char (point-min))
    (while (ignore-errors (org-occur-next-match 1))
      (org-show-context 'tags-tree)
      (org-show-subtree))))

(defun org-sparse-tree-show-matched ()
  "マッチした部分を表示します。"
  (interactive)
  (save-excursion
    (org-overview)

    (goto-char (point-min))
    (while (ignore-errors (org-occur-next-match 1))
      (org-show-context 'tags-tree))))

;; この関数は org-cycle-internal-global を元に修正しています。
(defun org-sparse-tree-cycle-internal ()
  "Do the sparse tree cycling action."
  ;; Rotate overview => sparse-tree-show-matched => sparse-tree-show-all => contents => show all

  ;; Hack to avoid display of messages for .org  attachments in Gnus
  (let ((ga (string-match "\\*fontification" (buffer-name))))
    (cond
     ((and (eq last-command this-command)
           (eq org-cycle-global-status 'sparse-tree-show-all))
      ;; We just created the overview - now do table of contents
      ;; This can be slow in very large buffers, so indicate action
      (run-hook-with-args 'org-pre-cycle-hook 'contents)
      (unless ga (org-unlogged-message "CONTENTS..."))
      (org-content)
      (unless ga (org-unlogged-message "CONTENTS...done"))
      (setq org-cycle-global-status 'contents)
      (run-hook-with-args 'org-cycle-hook 'contents))

     ((and (eq last-command this-command)
           (eq org-cycle-global-status 'contents))
      ;; We just showed the table of contents - now show everything
      (run-hook-with-args 'org-pre-cycle-hook 'all)
      (org-show-all '(headings blocks))
      (unless ga (org-unlogged-message "SHOW ALL"))
      (setq org-cycle-global-status 'all)
      (run-hook-with-args 'org-cycle-hook 'all))

     ((and (eq last-command this-command)
      ;; sparse tree show matched
           (eq org-cycle-global-status 'overview))
      (org-sparse-tree-show-matched)
      (setq org-cycle-global-status 'sparse-tree-show-matched))

     ((and (eq last-command this-command)
           (eq org-cycle-global-status 'sparse-tree-show-matched))
      ;; sparse tree show all
      (org-sparse-tree-show-all)
      (setq org-cycle-global-status 'sparse-tree-show-all))

     (t
      ;; overview
      (run-hook-with-args 'org-pre-cycle-hook 'overview)
      (org-overview)
      (unless ga (org-unlogged-message "OVERVIEW"))
      (setq org-cycle-global-status 'overview)
      (run-hook-with-args 'org-cycle-hook 'overview)))))

(defun org-sparse-tree-shifttab-advice (oldfun arg)
  (if org-occur-highlights
      ;; ハイライトがある
      (org-sparse-tree-cycle-internal)
    ;; 元の関数を呼ぶ
    (funcall oldfun arg)))

;; org-shifttabをオーバーライドする
(advice-add 'org-shifttab :around #'org-sparse-tree-shifttab-advice)