2021-12-16

jpgファイルの撮影日時と撮影場所をEmacs Lispで取得する方法(exif.el)

(2021-12-17追記:末尾に色々まとめて修正したコードを追加しました)

(2021-12-19追記:一部のJPEGファイル(XMPが入っているなど)が読み込めない問題も修正しました)

Emacsから写真の撮影日時と撮影場所を取得しようと思ったのですが、適当な外部ツールを呼び出せば良いのかなと思って調べていたところEmacs27にはexif.elというものが標準で入っていることに気がつきました。

試しに手元にあった画像を exif-parse-file 関数で読み取ってみました。

(require 'exif)
(exif-parse-file "~/tmp/20190826_163620.jpg"))

結果は次のようになりました。

((:tag 256 :tag-name nil :format 4 :format-type long :value 4032)
 (:tag 257 :tag-name nil :format 4 :format-type long :value 3024)
 (:tag 258 :tag-name nil :format 3 :format-type short :value "......")
 (:tag 262 :tag-name nil :format 3 :format-type short :value 2)
 (:tag 271 :tag-name make :format 2 :format-type ascii :value "Google")
 (:tag 272 :tag-name model :format 2 :format-type ascii :value "Pixel 3")
 (:tag 274 :tag-name orientation :format 3 :format-type short :value 1)
 (:tag 277 :tag-name nil :format 3 :format-type short :value 3)
 (:tag 282 :tag-name x-resolution :format 5 :format-type rational :value
       (720000 . 10000))
 (:tag 283 :tag-name y-resolution :format 5 :format-type rational :value
       (720000 . 10000))
 (:tag 296 :tag-name resolution-unit :format 3 :format-type short :value 2)
 (:tag 305 :tag-name software :format 2 :format-type ascii :value "Adobe Photoshop CS6 (Windows)")
 (:tag 306 :tag-name date-time :format 2 :format-type ascii :value "2019:08:28 18:19:45")
 (:tag 531 :tag-name nil :format 3 :format-type short :value 1)
 (:tag 34665 :tag-name nil :format 4 :format-type long :value 296)
 (:tag 34853 :tag-name nil :format 4 :format-type long :value 920)
 (:tag 259 :tag-name nil :format 3 :format-type short :value 6)
 (:tag 282 :tag-name x-resolution :format 5 :format-type rational :value
       (72 . 1))
 (:tag 283 :tag-name y-resolution :format 5 :format-type rational :value
       (72 . 1))
 (:tag 296 :tag-name resolution-unit :format 3 :format-type short :value 2)
 (:tag 513 :tag-name nil :format 4 :format-type long :value 1266)
 (:tag 514 :tag-name nil :format 4 :format-type long :value 7524))

:tag-nameexif-tag-alist に設定されている10種類以外はnilとなっています。

;; exif.elより
(defvar exif-tag-alist
  '((11 processing-software)
    (271 make)
    (272 model)
    (274 orientation)
    (282 x-resolution)
    (283 y-resolution)
    (296 resolution-unit)
    (305 software)
    (306 date-time)
    (315 artist))
  "Alist of tag values and their names.")

Exifには膨大な量のタグが定義されているのでとても全ては網羅できないでしょう。撮影日時や場所に関するtag-nameもここには設定されていません(date-timeは最終更新日時です)。

なので必要な情報は :tag の数値から判断する必要があります。タグの種類についてはCIPA DC-X008-2019-J(Exif 2.32)あたりを見れば良いようです。

exif-parse-file 関数が返したリストは 0th IFD (Image File Directory) というもので、その中には撮影日時や撮影場所といった細かい情報は直接入っていません。撮影日時はExif IFD Pointer(タグ番号34665)の指す先に、場所はGPS Info IFD Pointer(タグ番号34853)の指す先にあります。各Pointerの値は共に一つの整数値(上の写真の場合は296と920)となっていて、情報はその整数値(オフセット)が指し示す先に別途格納されています。exif.elの作者のページ(Parsing Exif Data – Random Thoughts)によれば画像の回転に関するプロパティを取得するために作成したようなので、0th IFD内のorientation(タグ番号274)が読めれば十分でありPointerの先までは読み込んでいないのでしょう。

上の写真のExif IFD Pointerの値は296、GPS Info IFD Pointerの値は920。これらはどこからのオフセットなのでしょうか。exif.elを読んでいくと、 exif-parse-fileexif-parse-bufferexif--parse-jpegexif--parse-exif-chunkexif--parse-directory と処理が流れていることが分かります。ファイル冒頭のコメントによれば全てのオフセットは IIまたはMM で始まるチャンクの先頭からの相対値ということなので、 exif--parse-exif-chunk の中で (delete-region (point-min) (point)) した後のバッファ内のポイント位置-1がオフセットと対応することになります(Emacsのバッファ内ポイント位置は1から始まるのことに注意)。 delete-region で不要な部分を削除することで (goto-char (1+ offset)) という単純な式でジャンプできるようにしているのだと思います。

うーんどうしましょうね。

任意のオフセットからIFDを読み込むにはgoto-charでポイントを移動した上でexif–parse-directoryを呼び出せば良いのですが、肝心のデータを格納したバッファを保持しておく方法が用意されていません。exif-parse-bufferはExifで始まるチャンク全体を一時的なバッファに格納しますが、0th IFDを読み込んだ後にすぐに捨ててしまいます。そこに追加の処理を挟めるようにはできていません。ちゃんとやるならこの関数を切り刻んで再構成するよりありませんが……。

とりあえず exif–parse-directory を一時的に上書きして動作を変えてしまいましょうか。値の読み込みが終わり、バッファにまだアクセスでき、tagの判別ができるポイントがそこしかないので。

(defun my-exif-prop-find (exif tag)
  (seq-find (lambda (e) (equal (plist-get e :tag) tag)) exif))
(defun my-exif-parse-file (file)
  (cl-letf* (((symbol-function 'exif--parse-directory-old)
              (symbol-function 'exif--parse-directory))
             ((symbol-function 'exif--parse-directory)
              (lambda (le)
                (let ((exif (exif--parse-directory-old le)) ;;元の関数を呼び出す
                      (pointer-tags '(34665 34853))) ;;Exif IFD Pointer, GPS Info IFD Pointer
                  (dolist (tag pointer-tags)
                    (let* ((property (my-exif-prop-find exif tag))
                           (offset (plist-get property :value)))
                      (when (integerp offset)
                        (goto-char (1+ offset))
                        ;; :valueのオフセットから情報を読み取り、:pointeeとして追加する
                        (nconc property (list :pointee
                                              (exif--parse-directory le))))))
                  exif))))
    (exif-parse-file file)))

(my-exif-parse-file "~/tmp/20190826_163620.jpg")

実行結果は次のようになります。

((:tag 256 :tag-name nil :format 4 :format-type long :value 4032)
 (:tag 257 :tag-name nil :format 4 :format-type long :value 3024)
 (:tag 258 :tag-name nil :format 3 :format-type short :value "......")
 (:tag 262 :tag-name nil :format 3 :format-type short :value 2)
 (:tag 271 :tag-name make :format 2 :format-type ascii :value "Google")
 (:tag 272 :tag-name model :format 2 :format-type ascii :value "Pixel 3")
 (:tag 274 :tag-name orientation :format 3 :format-type short :value 1)
 (:tag 277 :tag-name nil :format 3 :format-type short :value 3)
 (:tag 282 :tag-name x-resolution :format 5 :format-type rational :value
       (720000 . 10000))
 (:tag 283 :tag-name y-resolution :format 5 :format-type rational :value
       (720000 . 10000))
 (:tag 296 :tag-name resolution-unit :format 3 :format-type short :value 2)
 (:tag 305 :tag-name software :format 2 :format-type ascii :value "Adobe Photoshop CS6 (Windows)")
 (:tag 306 :tag-name date-time :format 2 :format-type ascii :value "2019:08:28 18:19:45")
 (:tag 531 :tag-name nil :format 3 :format-type short :value 1)
 (:tag 34665 :tag-name nil :format 4 :format-type long :value 296 :pointee
       ((:tag 33434 :tag-name nil :format 5 :format-type rational :value
              (810 . 1000000))
        (:tag 33437 :tag-name nil :format 5 :format-type rational :value
              (180 . 100))
        (:tag 34850 :tag-name nil :format 3 :format-type short :value 2)
        (:tag 34855 :tag-name nil :format 3 :format-type short :value 41)
        (:tag 36864 :tag-name nil :format 7 :format-type unknown :value 808596016)
        (:tag 36867 :tag-name nil :format 2 :format-type ascii :value "2019:08:26 16:36:20")
        (:tag 36868 :tag-name nil :format 2 :format-type ascii :value "2019:08:26 16:36:20")
        (:tag 37121 :tag-name nil :format 7 :format-type unknown :value 197121)
        (:tag 37377 :tag-name nil :format 10 :format-type unknown :value 802)
        (:tag 37378 :tag-name nil :format 5 :format-type rational :value
              (170 . 100))
        (:tag 37379 :tag-name nil :format 10 :format-type unknown :value 818)
        (:tag 37380 :tag-name nil :format 10 :format-type unknown :value 826)
        (:tag 37381 :tag-name nil :format 5 :format-type rational :value
              (170 . 100))
        (:tag 37382 :tag-name nil :format 5 :format-type rational :value
              (4294967295 . 1))
        (:tag 37383 :tag-name nil :format 3 :format-type short :value 2)
        (:tag 37385 :tag-name nil :format 3 :format-type short :value 16)
        (:tag 37386 :tag-name nil :format 5 :format-type rational :value
              (4440 . 1000))
        (:tag 37520 :tag-name nil :format 2 :format-type ascii :value "286725")
        (:tag 37521 :tag-name nil :format 2 :format-type ascii :value "286725")
        (:tag 37522 :tag-name nil :format 2 :format-type ascii :value "286725")
        (:tag 40960 :tag-name nil :format 7 :format-type unknown :value 808464688)
        (:tag 40961 :tag-name nil :format 3 :format-type short :value 1)
        (:tag 40962 :tag-name nil :format 4 :format-type long :value 1280)
        (:tag 40963 :tag-name nil :format 4 :format-type long :value 960)
        (:tag 40965 :tag-name nil :format 4 :format-type long :value 888)
        (:tag 41495 :tag-name nil :format 3 :format-type short :value 2)
        (:tag 41729 :tag-name nil :format 7 :format-type unknown :value 1)
        (:tag 41985 :tag-name nil :format 3 :format-type short :value 1)
        (:tag 41986 :tag-name nil :format 3 :format-type short :value 0)
        (:tag 41987 :tag-name nil :format 3 :format-type short :value 0)
        (:tag 41988 :tag-name nil :format 5 :format-type rational :value
              (0 . 1))
        (:tag 41989 :tag-name nil :format 3 :format-type short :value 27)
        (:tag 41990 :tag-name nil :format 3 :format-type short :value 0)
        (:tag 41992 :tag-name nil :format 3 :format-type short :value 0)
        (:tag 41993 :tag-name nil :format 3 :format-type short :value 0)
        (:tag 41994 :tag-name nil :format 3 :format-type short :value 0)
        (:tag 41996 :tag-name nil :format 3 :format-type short :value 3)))
 (:tag 34853 :tag-name nil :format 4 :format-type long :value 920 :pointee
       ((:tag 0 :tag-name nil :format 1 :format-type byte :value 514)
        (:tag 1 :tag-name nil :format 2 :format-type ascii :value "N")
        (:tag 2 :tag-name nil :format 5 :format-type rational :value
              ((36 . 1)
               (17 . 1)
               (4154 . 100)))
        (:tag 3 :tag-name nil :format 2 :format-type ascii :value "E")
        (:tag 4 :tag-name nil :format 5 :format-type rational :value
              ((137 . 1)
               (43 . 1)
               (1775 . 100)))
        (:tag 5 :tag-name nil :format 1 :format-type byte :value 0)
        (:tag 6 :tag-name nil :format 5 :format-type rational :value
              (269007 . 100))
        (:tag 7 :tag-name nil :format 5 :format-type rational :value
              ((7 . 1)
               (36 . 1)
               (16 . 1)))
        (:tag 11 :tag-name processing-software :format 5 :format-type rational :value
              (5029 . 1000))
        (:tag 27 :tag-name nil :format 7 :format-type unknown :value "ASCII...fused")
        (:tag 29 :tag-name nil :format 2 :format-type ascii :value "2019:08:26")))
 (:tag 259 :tag-name nil :format 3 :format-type short :value 6)
 (:tag 282 :tag-name x-resolution :format 5 :format-type rational :value
       (72 . 1))
 (:tag 283 :tag-name y-resolution :format 5 :format-type rational :value
       (72 . 1))
 (:tag 296 :tag-name resolution-unit :format 3 :format-type short :value 2)
 (:tag 513 :tag-name nil :format 4 :format-type long :value 1266)
 (:tag 514 :tag-name nil :format 4 :format-type long :value 7524))

:tag 34665の部分にEXIFデータが、:tag 34853の部分にGPS情報が :pointee プロパティとして追加されました。

試しに撮影日時を取得してみましょう。撮影日時の格納場所は34665(Exif IFD Pointer)が指している先の36867(DateTimeOriginal)です。

(defun my-exif-prop-value (exif tag &optional key)
  (plist-get (my-exif-prop-find exif tag) (or key :value)))

(let* ((exif (my-exif-parse-file "~/tmp/20190826_163620.jpg"))
       (exif-ifd (my-exif-prop-value exif 34665 :pointee))
       (date-time-original (my-exif-prop-value exif-ifd 36867)))
  date-time-original)
"2019:08:26 16:36:20"

いくつか別のカメラで撮影したファイルも確認してみましたが、現地時間で記録されているように見えます。最近の写真だと:tag 36881 としてタイムゾーン(“+09:00”)が付いているものもあるようです。

続いてGPS情報。

(let* ((exif (my-exif-parse-file "~/tmp/20190826_163620.jpg"))
       (gps-ifd (my-exif-prop-value exif 34853 :pointee)))
  (list
    (my-exif-prop-value gps-ifd 1)
    (my-exif-prop-value gps-ifd 2)
    (my-exif-prop-value gps-ifd 3)
    (my-exif-prop-value gps-ifd 4)))
(N (36 . 1) E (137 . 1))

あれ??? なんだか変な結果になっていますね。緯度経度は「度分秒」三つの分数で表現されているはずなのですがどうやら一つしか読み取っていないようです。

うー、しょうがないですねぇ。 exif--process-value を直接差し替えてしまいましょう。

(defun exif--process-value (value type le)
  "Do type-based post-processing of the value."
  (cl-case type
    ;; Chop off trailing zero byte.
    ('ascii (substring value 0 (1- (length value))))
    ('rational (with-temp-buffer
                 (set-buffer-multibyte nil)
                 (insert value)
                 (goto-char (point-min))
                 ;; ここから
                 (let* ((num-values (/ (length value) 8))
                        (nums (cl-loop repeat num-values
                                       collect (cons (exif--read-number 4 le)
                                                     (exif--read-number 4 le)))))
                   (if (= num-values 1)
                       (car nums)
                     nums))
                 ;; ここまで修正
                 ))
    (otherwise value)))

本当は分数以外の型も同じようにしなければならないはずですが、まぁ、とりあえずということで。(追記:修正したものを末尾に載せました)

これを使うと緯度経度が正しく三つの分数で取得できるようになります。

(let* ((exif (my-exif-parse-file "~/tmp/20190826_163620.jpg"))
       (gps-ifd (my-exif-prop-value exif 34853 :pointee)))
  (list
    (my-exif-prop-value gps-ifd 1)
    (my-exif-prop-value gps-ifd 2)
    (my-exif-prop-value gps-ifd 3)
    (my-exif-prop-value gps-ifd 4)))
("N"
 ((36 . 1)
  (17 . 1)
  (4154 . 100))
 "E"
 ((137 . 1)
  (43 . 1)
  (1775 . 100)))

今度はうまく行きました。小数に直すなら次のようになります。

(defun my-exif-3rationals-to-float (v neg)
  (let ((value (+
                (/ (caar v) (* 1.0 (cdar v)))
                (/ (caadr v) (* 60.0 (cdadr v)))
                (/ (caaddr v) (* 3600.0 (cdaddr v))))))
    (if neg (- value) value)))

(let* ((exif (my-exif-parse-file "~/tmp/20190826_163620.jpg"))
       (gps (my-exif-prop-value exif 34853 :pointee)))
  (format "%.6f,%.6f"
          (my-exif-3rationals-to-float (my-exif-prop-value gps 2)
                                       (string= (my-exif-prop-value gps 1) "S"))
          (my-exif-3rationals-to-float (my-exif-prop-value gps 4)
                                       (string= (my-exif-prop-value gps 1) "W"))))
"36.294872,137.721597"

このように色々一筋縄ではいかない様子を見ると大人しく外部ツールを使えよという声が聞こえてきそうですが、一応このような方法でも取得できるということで。ちなみにimage-diredはexiftoolを使うみたいです。

せっかく標準で入っているのに活用しないのは何だか勿体ないですね。ただ、jpgファイル全体を一度バッファに読み込む実装になっているので、巨大なjpgファイルの場合あまり効率は良くないかもしれません。これは insert-file-contents-literallybegend 引数で改善できるかもしれません。

(2021-12-17追記: Emacs27のexif.elにはビッグエンディアンのファイルが正しく読み込めないバグが二箇所ありました。一箇所は最新版では修正されていますが、もう一箇所はまだ修正されていないようです(for value = (exif–read-number 4 le) の部分)。また、上で書いたように複数の値を正しく読み込めない問題もありました。それらを修正したのが以下のバージョンになります)

(2021-12-19追記: Exif以外のAPP1セグメントを考慮していないバグも修正しました。例えばXMPというメタ情報が入っているとエラーになって読み込めませんでした。 exif--parse-jpeg 関数を my-exif--find-app1-exif-in-jpeg 関数で置き換えて修正しています)

20211219_my-exif.el

(require 'exif)

(defun my-exif-prop-find (exif tag)
  (seq-find (lambda (e) (equal (plist-get e :tag) tag)) exif))

(defun my-exif-prop-value (exif tag &optional key)
  (plist-get (my-exif-prop-find exif tag) (or key :value)))

(defun my-exif-3rationals-to-float (v neg)
  (let ((value (+
                (/ (caar v) (* 1.0 (cdar v)))
                (/ (caadr v) (* 60.0 (cdadr v)))
                (/ (caaddr v) (* 3600.0 (cdaddr v))))))
    (if neg (- value) value)))

;;

(defun my-exif-parse-file (file)
  (cl-letf (((symbol-function 'exif--parse-jpeg)
             #'my-exif--find-app1-exif-in-jpeg) ;; [BugFix] Support APP1 segments that are not Exif (Such as XMP)
            ((symbol-function 'exif--parse-exif-chunk)
             #'my-exif--parse-exif-chunk))
    (exif-parse-file file)))

(defun my-exif--find-app1-exif-in-jpeg ()
  (unless (= (exif--read-number-be 2) #xffd8) ; SOI (start of image)
    (signal 'exif-error "Not a valid JPEG file"))
  (cl-loop for segment = (exif--read-number-be 2)
           for size = (exif--read-number-be 2)
           ;; Stop parsing when we get to SOS (start of stream);
           ;; this is when the image itself starts, and there will
           ;; be no more chunks of interest after that.
           while (not (= segment #xffda)) ;;FFDA=SOS
           do (if (and (= segment #xffe1) ;;FFE1=APP1
                       (equal (save-excursion (exif--read-chunk 6))
                              (string ?E ?x ?i ?f ?\0 ?\0)))
                  ;; Return APP1 Exif
                  ;; (Matched to return value of exif--parse-jpeg)
                  (cl-return (list
                              (cons segment (exif--read-chunk (- size 2)))))
                ;; Skip segment
                (forward-char (- size 2)))))

(defun my-exif--parse-exif-chunk (data)
  (with-temp-buffer
    (set-buffer-multibyte nil)
    (insert data)
    (goto-char (point-min))
    ;; The Exif data is in the APP1 JPEG chunk and starts with
    ;; "Exif\0\0".
    (unless (equal (exif--read-chunk 6) (string ?E ?x ?i ?f ?\0 ?\0))
      (signal 'exif-error "Not a valid Exif chunk"))
    (delete-region (point-min) (point))
    (let* ((endian-marker (exif--read-chunk 2))
           (le (cond
                ;; "Motorola" is big-endian.
                ((equal endian-marker "MM")
                 nil)
                ;; "Intel" is little-endian.
                ((equal endian-marker "II")
                 t)
                (t
                 (signal 'exif-error
                         (format "Invalid endian-ness %s" endian-marker))))))
      ;; Another magical number.
      (unless (= (exif--read-number 2 le) #x002a)
        (signal 'exif-error "Invalid TIFF header length"))
      (let ((offset (exif--read-number 4 le))) ;; <==== [BugFix] 2 => 4 ====
        ;; Jump to where the IFD (directory) starts and parse it.
        (when (> (1+ offset) (point-max))
          (signal 'exif-error "Invalid IFD (directory) offset"))
        (goto-char (1+ offset))
        (my-exif--parse-directory le)))))

(defun my-exif--parse-directory (le)
  (let ((dir
         (cl-loop repeat (exif--read-number 2 le)
                  collect (my-exif--read-value le))))
    (let ((next (exif--read-number 4 le)))
      (if (> next 0)
          ;; There's more than one directory; if so, jump to it and
          ;; keep parsing.
          (progn
            (when (> (1+ next) (point-max))
              (signal 'exif-error "Invalid IFD (directory) next-offset"))
            (goto-char (1+ next))
            (nconc dir (my-exif--parse-directory le)))
        ;; We've reached the end of the directories.
        dir))))

(defvar my-exif-pointer-tags '(34665 ;;Exif IFD Pointer
                               34853)) ;;GPS Info IFD Pointer

(defun my-exif--read-value (le)
  ;; [Add] Support multiple components
  ;; [BugFix] Reading small value length < 4 and big-endian
  (let* ((tag (exif--read-number 2 le))
         (format (exif--read-number 2 le))
         (field-format (my-exif--field-format format))
         (type (car field-format))
         (bytes/component (cdr field-format))
         (num-components (exif--read-number 4 le))
         (num-bytes (* num-components bytes/component))
         (components
          (save-excursion
            (when (> num-bytes 4)
              ;; If the length of the data is
              ;; more than 4 bytes, then it's
              ;; actually stored after this
              ;; directory, and the value
              ;; here is just the offset to
              ;; use to find the data.
              (let ((offset (exif--read-number 4 le)))
                (when (> (+ (1+ offset) num-bytes)
                         (point-max))
                  (signal 'exif-error
                          "Premature end of file"))
                (goto-char (1+ offset))))

            (pcase type
              ;;@todo support signed
              ;;@todo support float and double
              ((or 'byte 'short 'long
                   's-byte 's-short 's-long)
               (cl-loop repeat num-components
                        collect (exif--read-number bytes/component le)))
              ((or 'rational 's-rational)
               (cl-loop repeat num-components
                        collect (cons
                                 (exif--read-number 4 le)
                                 (exif--read-number 4 le))))
              ('ascii
               (buffer-substring (point) (+ (point) num-bytes -1)));;Chop off trailing zero byte.
              ('undefined
               (buffer-substring (point) (+ (point) num-bytes)))
              (_
               nil))))
         (value (cond
                 ((eq type 'ascii)
                  components)
                 ((eq type 'undefined)
                  components)
                 ((= num-components 1)
                  (car components))
                 (t
                  components)))
         (pointee (when (and (memq tag my-exif-pointer-tags)
                             (integerp value))
                    (save-excursion
                      (goto-char (1+ value))
                      (my-exif--parse-directory le)))))
    ;; Skip Value (4 bytes)
    (goto-char (+ (point) 4))

    (nconc
     (list
      :tag tag
      :tag-name (cadr (assq tag my-exif-tag-alist))
      :format format
      :format-type (car field-format)
      :value value)
     (when pointee
       (list :pointee pointee)))))

(defun my-exif--field-format (number)
  (cl-case number
    (1 (cons 'byte 1))
    (2 (cons 'ascii 1))
    (3 (cons 'short 2))
    (4 (cons 'long 4))
    (5 (cons 'rational 8))
    (6 (cons 's-byte 1))
    (7 (cons 'undefined 1))
    (8 (cons 's-short 2))
    (9 (cons 's-long 4))
    (10 (cons 's-rational 8))
    (11 (cons 'float 4))
    (12 (cons 'double 8))
    (otherwise (cons 'unknown 1))))

(defvar my-exif-tag-alist
  '((11 processing-software)
    (256 image-width)
    (257 image-length)
    (258 bits-per-sample)
    (259 compression)
    (262 photometric-interpretation)
    (270 image-description)
    (271 make)
    (272 model)
    (273 strip-offsets)
    (274 orientation)
    (277 samples-per-pixel)
    (282 x-resolution)
    (283 y-resolution)
    (296 resolution-unit)
    (305 software)
    (306 date-time)
    (315 artist)
    (513 jpeg-interchange-format)
    (514 jpeg-interchange-format-length)
    (531 ycbcr-positioning)
    (33434 exposure-time)
    (33437 f-number)
    (34665 exif-ifd-pointer)
    (34850 exposure-program)
    (34853 gps-info-ifd-pointer)
    (34855 iso-speed-ratings)
    (36864 exif-version)
    (36867 date-time-original)
    (36868 date-time-digitized)
    (37121 components-configuration)
    (37377 shutter-speed-value)
    (37378 aperture-value)
    (37379 brightness-value)
    (37380 exposure-bias-value)
    (37381 max-aperture-value)
    (37382 subject-distance)
    (37383 metering-mode)
    (37384 light-source)
    (37385 flash)
    (37386 focal-length)
    (37520 sub-sec-time)
    (37521 sub-sec-time-original)
    (37522 sub-sec-time-digitized)
    (40960 flashpix-version)
    (40961 color-space)
    (40962 pixel-x-dimension)
    (40963 pixel-y-dimension)
    (40964 related-sound-file)
    (40965 interoperability-tag)
    (41495 sensing-method)
    (41729 scene-type)
    (41985 custom-rendered)
    (41986 exposure-mode)
    (41987 white-balance)
    (41988 digital-zoom-ratio)
    (41989 focal-length-in-35mm-film)
    (41990 scene-capture-type)
    (41991 gain-control)
    (41992 contrast)
    (41993 saturation)
    (41994 sharpness)
    (41995 device-setting-description)
    (41996 subject-distance-range))
  "Alist of tag values and their names.")

;;

(defun my-exif-encode-date-time (exif-date-time-str)
  (when exif-date-time-str
    (encode-time
     (nconc
      (nreverse
       (mapcar #'string-to-number
               (split-string exif-date-time-str "[ :]")))
      (list nil nil nil)))))

(defun my-exif-date-time-original (exif)
  (when-let ((exif-ifd (my-exif-prop-value exif 34665 :pointee))
             (date-time-original (my-exif-prop-value exif-ifd 36867)))
    (my-exif-encode-date-time date-time-original)))

(defun my-exif-latlng (exif)
  (when-let ((gps (my-exif-prop-value exif 34853 :pointee))
             (lat-ref (my-exif-prop-value gps 1))
             (lat (my-exif-prop-value gps 2))
             (lng-ref (my-exif-prop-value gps 3))
             (lng (my-exif-prop-value gps 4)))
    (cons
     (my-exif-3rationals-to-float lat
                                  (string= lat-ref "S"))
     (my-exif-3rationals-to-float lng
                                  (string= lng-ref "W")))))

これを使うと撮影日時と撮影場所は次のコードで取得できます。

(let ((exif (my-exif-parse-file "~/tmp/20190826_163620.jpg")))
  (list
   (format-time-string "%Y-%m-%d %H:%M:%S" (my-exif-date-time-original exif))
   (my-exif-latlng exif)))
("2019-08-26 16:36:20"
 (36.29487222222222 . 137.72159722222221))

Pingback / Trackback