companyからcorfuへ移行～自動と手動で補完候補を変える

corfuはcompanyよりは幾分素直で扱いやすい印象。

corfuの設定:

(2024-02-18追記: Corfuの自動補完で候補の存在を伝える事と候補を選べるようにする事を分離するで設定を書き直したので以下のコードは古い)

(setq corfu-cycle t) ;; 候補の最初と最後を行き来出来るようにする。
(setq corfu-auto t) ;; 自動的に補完候補を出す。
(setq corfu-preselect 'prompt) ;; 最初の候補を選択しない。誤入力が多すぎるので。

;; 無選択時のRETはquitだけでなく改行もする。
;; (2024-02-15修正:my-corfu-だと素早くC-M-iの後素早くRETを押したときに正しく補完されない。コマンド名がcorfu-で始まっているときだけupdateしている場所があるので)
(defun corfu-my-insert-or-newline ()
  (interactive)
  (if (>= corfu--index 0)
      (corfu--insert 'finished)
    (corfu-quit)
    ;; (2024-02-15修正:インタラクティブじゃないとインデントされなかったりする)
    (call-interactively 'newline)))
(with-eval-after-load "corfu"
  (define-key corfu-map (kbd "RET") 'corfu-my-insert-or-newline))

(global-corfu-mode)

;; lsp-modeでcorfuを使う。
;; (see: https://github.com/minad/corfu/wiki#example-configuration-with-flex)
(setq lsp-completion-provider :none)
(defun my-lsp-mode-setup-completion ()
  (setf (alist-get 'styles
                   (alist-get 'lsp-capf completion-category-defaults))
        '(flex)))
(add-hook 'lsp-completion-mode-hook #'my-lsp-mode-setup-completion)

;; corfuの候補リストにアイコンを表示する。
(setq kind-icon-default-face 'corfu-default)
(add-to-list 'corfu-margin-formatters #'kind-icon-margin-formatter)

(corfu-auto=tで)自動的に補完候補を出しつつ自動的に最初の候補を選択する(corfu-preselectが'firstや'valid)というのは誤操作を引き起こす可能性がある。何かを入力してRETやTABを押したら自動的に出てきた補完候補の方を意図せず選んでしまったというようなことが起こりえる。そのためにcorfu-preselectを'promptにして明示的に選ばなければ補完しないように設定した。

それでも何かを入力してC-n RETを押すようなシチュエーションでは下に移動して改行するつもりが最初の候補を選択して確定してしまうので、結局誤入力は完全には回避できなかった。なので自動的に出す時の候補をできるだけ少なくする(自動ではあまり候補を出さない)ようにしてみた。補完候補(バックエンド)は completion-at-point-functions (capf)という元々Emacsに備わっている仕組みに一本化されているので、それを調整する。

completion-at-point-functionsの設定:

;; 補完候補を出すときの文脈を特定

(defvar my-capf-context nil)

;; (2022-10-26修正: corfu--auto-complete => corfu--auto-complete-deferred)
(defun my-capf--corfu--auto-complete-deferred (old-fun &rest args)
  ;; corfu-autoの作用で補完候補を出すときに呼び出される。
  (let (;; 自動で補完候補を出す文脈だということを変数に記録する。
        (my-capf-context 'in-corfu--auto-complete-deferred)
        ;; 2024-02-14追記:
        ;; 自動で補完候補を出すときは必ずbasicスタイルのみを使うべし！
        ;; 先頭すら一致していない候補をバリバリ出されたら鬱陶しい！
        (completion-styles '(basic)))
    ;; 元の処理
    (apply old-fun args)))
(advice-add 'corfu--auto-complete-deferred :around #'my-capf--corfu--auto-complete-deferred)

;; 追加の補完関数

(defun my-capf-additional ()
  (pcase my-capf-context
    ('in-corfu--auto-complete-deferred
     ;; 自動補完の場合は確度の高い候補しか出さない。
     nil)
    (_
     ;; 手動補完の場合は積極的にいろんな候補を出す。
     (my-capf-manual))))
(add-hook 'completion-at-point-functions #'my-capf-additional 100)

;; 手動補完時の補完関数

(defvar my-capf-manual nil)
(defun my-capf-manual ()
  ;; capeパッケージの読み込みを遅延させる。
  (unless my-capf-manual
    (setq my-capf-manual
          ;; いろんな補完候補を合成する。
          (cape-super-capf
           #'cape-file #'cape-dabbrev #'cape-abbrev #'cape-line)))
  (funcall my-capf-manual))

自動的に補完候補を出す場合は元々モードに備わっているような補完候補しか出さないようにした。プログラミング言語用のモードの場合は文法に則した候補が出るのでそれほど邪魔にならないと思われる。

逆にC-M-iで手動で補完候補を出す場合はcapeパッケージの多種多様な補完候補を利用する。手動で出しているのだから多少確度の低い候補が出てきても構わない。

cape-super-capfで複数のバックエンドをマージしている。

capeは他にもcompany用バックエンドをcapfに変換するアダプタも持っている。手元にはorg-modeの「#+」行をより良く補完する自作のCompanyバックエンドがあるので、このアダプタでcorfu用に変換した。

今のところM-/はdabbrev-expandのままにしてある。

補完候補については不満なところがまだまだ沢山あるので逐一直していくつもりだ。completion-stylesも過剰な補完生成に一役買っているように見える。verticoにせよcorfuにせよ、どうも補完することばかりを優先して補完させたくないケースを軽視しているように見える。

(2024-02-15追記: Corfuの自動補完で候補の存在を伝える事と候補を選べるようにする事を分離するで設定を追加した)

Pingback / Trackback