(vertico-mode)
(setq vertico-cycle t) ;;最初と最後の候補を行き来できるようにする
(setq completion-styles '(basic substring partial-completion flex)) ;;適当

;; 大文字小文字の区別をしない
(setq read-file-name-completion-ignore-case t
      read-buffer-completion-ignore-case t
      completion-ignore-case t)

;; 候補更新時に最初の候補を選択しない (2023-03-19追記: verticoにカスタマイズ変数が追加された！ https://github.com/minad/vertico/commit/bedd146c3ffc236d746d088a94c3858eca0618d9 (Add vertico-preselect option (Fix #306) · minad/vertico@bedd146))
(setq vertico-preselect 'prompt)

;; (2023-04-18追記)
;; ただし、require-matchがt(やそれに類するもの)で入力が空ではなくマッ
;; チする候補がある場合は、その候補の先頭を選択する。
(defun my-vertico--recompute (orig-fun pt content &rest args)
  (let ((result (apply orig-fun pt content args)))
    (if (and (not (equal content "")) ;;入力が空の時は(require-matchであっても)defaultまたはnilを返すことになっている。
             (> (alist-get 'vertico--total result) 0)
             ;; completing-readの説明によれば
             ;; nil,confirm,confirm-after-completion以外はtのように
             ;; 振る舞うべき。
             (not (memq minibuffer--require-match
                        '(nil confirm confirm-after-completion))))
        (setf (alist-get 'vertico--index result) 0))
    result))
(advice-add #'vertico--recompute :around #'my-vertico--recompute)

;; 以下は過去のもの
;; ;; 候補更新時に最初の候補を選択しない (2022-12-01追記: vertico--allow-prompt-p関数が無くなって代わりに戻り値にvertico--allow-promptが増えたので修正)
;; (defun my-vertico--recompute (original-fun &rest args)
;;   ;; vertico--update-candidatesの最後の処理を置き換える。
;;   (let ((result (apply original-fun args)))
;;     (when result
;;       (let ((lock         (alist-get 'vertico--lock-candidate result))
;;             (allow-prompt (alist-get 'vertico--allow-prompt result))
;;             (index        (alist-get 'vertico--index result)))
;;         (when (and (not lock)
;;                    allow-prompt)
;;           ;; lockされておらず, require-matchじゃない場合は現在入力中の文字列を選択する。
;;           (setf (alist-get 'vertico--index result) -1))))
;;     result))
;; (advice-add #'vertico--recompute :around #'my-vertico--recompute)

;; ;; 候補更新時に最初の候補を選択しない (2022-10-24追記: 関数名や戻り値が変わったので修正)
;; (defun my-vertico--recompute (original-fun &rest args)
;;   ;; vertico--update-candidatesの最後の処理を置き換える。
;;   (let ((result (apply original-fun args)))
;;     (when result
;;       (let ((lock        (alist-get 'vertico--lock-candidate result))
;;             (def-missing (alist-get 'vertico--default-missing result))
;;             (index       (alist-get 'vertico--index result)))
;;         (when (and (not lock)
;;                    (let ((vertico--default-missing def-missing)) (vertico--allow-prompt-p)))
;;           ;; lockされておらず, require-matchじゃない場合は現在入力中の文字列を選択する。
;;           (setf (alist-get 'vertico--index result) -1))))
;;     result))
;; (advice-add #'vertico--recompute :around #'my-vertico--recompute)

;; ;; 候補更新時に最初の候補を選択しない (旧バージョン用)
;; (defun my-vertico--recompute-candidates (original-fun &rest args)
;;   ;; vertico--update-candidatesの最後の処理を置き換える
;;   (let ((result (apply original-fun args)))
;;     (when result
;;       (unless (nth 3 result) ;;3=index
;;         (setq vertico--lock-candidate nil)
;;         (setf (nth 3 result) ;;3=index
;;               (if (vertico--allow-prompt-selection-p)
;;                   ;; require-matchじゃない場合は現在入力中の文字列を選択する
;;                   -1
;;                 ;; require-matchの場合は最初の候補を選択する
;;                 0))))
;;     result))
;; (advice-add #'vertico--recompute-candidates :around #'my-vertico--recompute-candidates)

;; より簡単な方法としてRETをvertico-exit-inputにするという方法もある。
;; (define-key vertico-map [remap exit-minibuffer] #'vertico-exit-input)
;; しかし補完候補がハイライトされるので気持ち悪い。
;; プロンプトがハイライトされているべき。

(completing-read "商品: " '("ringo-ame" "ringo-cake" "ringo-juice"))

(completing-read "商品: " '("ringo-ame" "ringo-cake" "ringo-juice") nil t)

(setq corfu-cycle t) ;; 候補の最初と最後を行き来出来るようにする。
(setq corfu-auto t) ;; 自動的に補完候補を出す。
(setq corfu-preselect 'prompt) ;; 最初の候補を選択しない。誤入力が多すぎるので。

;; 無選択時のRETはquitだけでなく改行もする。
;; (2024-02-15修正:my-corfu-だと素早くC-M-iの後素早くRETを押したときに正しく補完されない。コマンド名がcorfu-で始まっているときだけupdateしている場所があるので)
(defun corfu-my-insert-or-newline ()
  (interactive)
  (if (>= corfu--index 0)
      (corfu--insert 'finished)
    (corfu-quit)
    ;; (2024-02-15修正:インタラクティブじゃないとインデントされなかったりする)
    (call-interactively 'newline)))
(with-eval-after-load "corfu"
  (define-key corfu-map (kbd "RET") 'corfu-my-insert-or-newline))

(global-corfu-mode)

;; lsp-modeでcorfuを使う。
;; (see: https://github.com/minad/corfu/wiki#example-configuration-with-flex)
(setq lsp-completion-provider :none)
(defun my-lsp-mode-setup-completion ()
  (setf (alist-get 'styles
                   (alist-get 'lsp-capf completion-category-defaults))
        '(flex)))
(add-hook 'lsp-completion-mode-hook #'my-lsp-mode-setup-completion)

;; corfuの候補リストにアイコンを表示する。
(setq kind-icon-default-face 'corfu-default)
(add-to-list 'corfu-margin-formatters #'kind-icon-margin-formatter)

;; 補完候補を出すときの文脈を特定

(defvar my-capf-context nil)

;; (2022-10-26修正: corfu--auto-complete => corfu--auto-complete-deferred)
(defun my-capf--corfu--auto-complete-deferred (old-fun &rest args)
  ;; corfu-autoの作用で補完候補を出すときに呼び出される。
  (let (;; 自動で補完候補を出す文脈だということを変数に記録する。
        (my-capf-context 'in-corfu--auto-complete-deferred)
        ;; 2024-02-14追記:
        ;; 自動で補完候補を出すときは必ずbasicスタイルのみを使うべし！
        ;; 先頭すら一致していない候補をバリバリ出されたら鬱陶しい！
        (completion-styles '(basic)))
    ;; 元の処理
    (apply old-fun args)))
(advice-add 'corfu--auto-complete-deferred :around #'my-capf--corfu--auto-complete-deferred)

;; 追加の補完関数

(defun my-capf-additional ()
  (pcase my-capf-context
    ('in-corfu--auto-complete-deferred
     ;; 自動補完の場合は確度の高い候補しか出さない。
     nil)
    (_
     ;; 手動補完の場合は積極的にいろんな候補を出す。
     (my-capf-manual))))
(add-hook 'completion-at-point-functions #'my-capf-additional 100)

;; 手動補完時の補完関数

(defvar my-capf-manual nil)
(defun my-capf-manual ()
  ;; capeパッケージの読み込みを遅延させる。
  (unless my-capf-manual
    (setq my-capf-manual
          ;; いろんな補完候補を合成する。
          (cape-super-capf
           #'cape-file #'cape-dabbrev #'cape-abbrev #'cape-line)))
  (funcall my-capf-manual))