皆さんは dired-dwim-target 変数を使ってますか？　diredでコピー先や移動先を良い感じに推測してくれる機能です。分割ウィンドウで他のディレクトリを開いているとコピー先や移動先をそのディレクトリにしてくれます。古からある二画面ファイラーなんかではおなじみの機能ですね。ついでにM-nで出る「未来の履歴」にもいくつか候補を設定しておいてくれます。(EmacsではM(Alt)-p(previousのp)で過去の履歴をたどれてM-n(next)で現在に戻ってこれますが、現在を越えてM-nを押すとこれから選びそうな候補が出てくるというUIの考え方が(一部で)あります)

それでコピーや移動のときには大変便利なのですが、ファイル名を変更するときにはよくミスを犯してしまうのです。なぜならファイル名の変更と移動は同じRキーに割り当てられているからです。名前の変更はファイルの移動と同じ、または逆にファイルの移動はディレクトリパスも含めた名前の変更と同じと考えられるからです。Unixではどちらもmvコマンドですし。それでファイル名を変更しようとRキーを押したとき、 dired-dwim-target が有効だとたまたま開いていた別のディレクトリが移動先として設定されてしまうわけです。それに気がつかずに新しいファイル名を入力してEnterを押すと、ファイル名も変わるのですが同時に別のディレクトリにファイルが飛んで行ってしまうわけです。ぎゃー！

というわけでどうにかならないのかなと。移動と名前の変更が同じキーになっているのが原因ですから、別のキーに割り当てて候補の出方を変えるというのも手です。小文字のrは使っていないのでここに「ファイル名変更(ディレクトリ変更不可)」を割り当てるとか。でも非標準の操作体系を増やすと別のマシンを使うときに戸惑うのであまりやりたくありません(いまさら！)。安全優先でRは名前変更のための候補を優先して出し、移動先の候補はM-nで出すだけで十分かもしれません。と、Twitterでつぶやいたのですが……

名前変更には wdired 使ってますhttps://t.co/y1GnMtOuAj https://t.co/ER3sWOqS6Y

— iquiw (@iquiw) July 26, 2021

「名前変更には wdired 使ってます」との天の声が。

なんとそんな使い分けの方法があったとは！

wdiredとはファイル一覧のファイル名部分をテキストエディタの要領で編集するとファイル名が変わってくれるという便利機能です。

しかし私がwdiredを使っていないのには理由がありまして、以前wdiredを試したときにファイル名の入力がうまくいかなかったり、うまく行っても表示がおかしくなったりしたのです。

というのも私はdired-details-rというファイルサイズやタイムスタンプなどの詳細をファイル名の右に出す拡張を作っていて、どうもそれが悪さをしているようなのです。

しかしそれを直してしまえばwdiredを使ってみるのもやぶさかではありません。

というわけで重い腰を上げて dired-details-r を直すことにしました。他にも色々直したいところがあったのでついでに直すことにしました。

• wdiredでファイル名を編集したときにファイル名の先頭でread-onlyエラーで書き替えられないことがあったり、書き替えられても書き替えた部分が表示されないことがある不具合を修正
• ファイル名の末尾にカーソル(ポイント)を合わせられない不具合を修正(詳細情報の右に飛ぶ。wdiredでファイル名の末尾に文字を追加すると追加した部分だけ詳細情報の右に表示される！)
• カスタマイズまわり(グループとか型とか)の修正
• マイナーモード化(dired-details-r-mode)
• 一部のファイルだけ更新がかかったときに列が乱れる不具合の修正
• "(" キーでの表示切り替えで元の表示形式(詳細の左表示)に戻せる機能を追加(wdiredでパーミッションを編集したい場合に備えて)
• 設定のデフォルト値の調整
• 導入方法の修正(以前はrequireするだけでしたが、マイナーモード化したので (dired-details-r-setup) を呼び出すか自分でマイナーモードを起動するか選択可能に)

以上を修正。

晴れてwdiredが正常に使えるようになりました。

wdiredでのファイル名変更手順は、C-x C-q で編集を開始し、ファイル名を書き替えてから C-c C-c または 再度C-x C-q。Rを押してファイル名を書くより面倒かなと思ったのですが案外違和感がありません。C-x C-qはリードオンリーモードの切り替えでよく使うキー操作です。通常diredはリードオンリーモードになっていてテキストを書き替えられませんが、リードオンリーモードを解除してファイル名部分を書き替えて確定、または再度リードオンリーモードを有効にする、というある意味自然な流れなのは知っていました。しかしそうは言ってもタイプ数が増えるのだから面倒だろうと思ってもいたのですが、想像していたよりも違和感なく素早く操作できます。しばらく名前の変更はwdired縛りで行こうと思います。一括変更はさすがに % m でマークして % R で正規表現置換した方が楽な気もしますがどうでしょうね。

色々ときっかけを頂いたiquiwさんありがとうございました。

neotreeを試してみたのですが、neo-smart-openをtにするとf8に割り当てたneotree-toggleを押したときに固まることがありました。普通のファイルを開いているときは固まらず、scratchやdiredでディレクトリを開いているときに固まるようです。

コードを追ってみたところ neo-buffer--select-file-node 関数の中で無限ループに陥ってしまう場所を見つけました。

https://github.com/jaypei/emacs-neotree/blob/98fe21334affaffe2334bf7c987edaf1980d2d0b/neotree.el#L1632

親ディレクトリへ移動するループで、ルートに到達したかの判定を"/"と比較することで行っています。Windowsでは"c:/"等がルートで何度neo-path--updirを適用しても決して"/"になりませんからいつまで経っても終わりません。

とりあえず"/"を"c:/"にしたら直ったのですが、それではあんまりなのでupdirしたときにパスが変化しなかったら終わらせるようにしてみました。

うまくadviceもかけられないしneotree.el読み込み後に関数まるごと再定義。neotreeはそんなに頻繁に更新されていないみたいなのでまあいいか。

(with-eval-after-load "neotree"
  (defun neo-buffer--select-file-node (file &optional recursive-p)
    "Select the node that corresponds to the FILE.
If RECURSIVE-P is non nil, find files will recursively."
    (let ((efile file)
          (iter-prev-dir nil) ;;ADD
          (iter-curr-dir nil)
          (file-node-find-p nil)
          (file-node-list nil))
      (unless (file-name-absolute-p efile)
        (setq efile (expand-file-name efile)))
      (setq iter-curr-dir efile)
      (catch 'return
        (while t
          (setq iter-prev-dir iter-curr-dir) ;;ADD
          (setq iter-curr-dir (neo-path--updir iter-curr-dir))
          (push iter-curr-dir file-node-list)
          (when (neo-path--file-equal-p iter-curr-dir neo-buffer--start-node)
            (setq file-node-find-p t)
            (throw 'return nil))
          (let ((niter-curr-dir (file-remote-p iter-curr-dir 'localname)))
            (unless niter-curr-dir
              (setq niter-curr-dir iter-curr-dir))
            (when (or (string= iter-curr-dir iter-prev-dir) ;;ADD
                      (neo-path--file-equal-p niter-curr-dir "/"))
              (setq file-node-find-p nil)
              (throw 'return nil)))))
      (when file-node-find-p
        (dolist (p file-node-list)
          (neo-buffer--set-expand p t))
        (neo-buffer--save-cursor-pos file)
        (neo-buffer--refresh nil)))))

ふとEmacs Lispマニュアルの Sound Output のところが目に入ったので試してみました。サウンドまわりは大昔に試してあまり良くなかった記憶がありますがその後どれだけ改善されたかな。

• GNU Emacs Lisp Reference Manual: Sound Output (公式)
• GNU Emacs Lisp Reference Manual: Sound Output (日本語)

マニュアルを読んでみると (play-sound '(sound :file "ファイルへのパス")) か (play-sound '(sound :data "サウンドデータ")) で鳴るみたいです。

試しにサイン波でも生成して鳴らしてみましょうか。

対応形式は.wav(RIFF)または.auと書いてあります。.auの方がヘッダーがシンプルなのでそれにしましょう。

• Sunオーディオファイル - Wikipedia

44.1KHzモノラルの16-bit PCMのヘッダーは文字列にすると ".snd\x00\x00\x00\x18\xff\xff\xff\xff\x00\x00\x00\x03\x00\x00\xac\x44\x00\x00\x00\x01" の24バイトですね(長さは不明ffffffffとしてあります)。各要素はビッグエンディアンな32-bit整数です。

16-bit PCMの各要素は負号付き整数みたいですね。-32767~0~32768。

うーん、どうしましょう。文字列バッファを先に確保して、そこにバイト列を埋めていく方が速度的に良さそうでしょうか？　(適当に文字列結合しまくる方が作るのは楽そうですが)

ひとまず16-bit, 32-bit整数を文字列化する関数を作り……

(defun my-snd-aset-i32 (bytearray index x)
  (aset bytearray index (logand 255 (ash x -24)))
  (aset bytearray (+ index 1) (logand 255 (ash x -16)))
  (aset bytearray (+ index 2) (logand 255 (ash x -8)))
  (aset bytearray (+ index 3) (logand 255 x)))

(defun my-snd-aset-i16 (bytearray index x)
  (aset bytearray index (logand 255 (ash x -8)))
  (aset bytearray (+ index 1) (logand 255 x)))

サイン波を生成する関数を作り……

(defconst my-snd-byte-size-i16 2)
(defconst my-snd-amplitude-i16 32767)

(defun my-snd-aset-sin-wave (dst-buffer dst-index num-samples wavelength)
  (let ((2pi/wavelength (/ (* 2 pi) wavelength))
        (i 0))
    (while (< i num-samples)
      (my-snd-aset-i16 dst-buffer dst-index
                       (truncate (* my-snd-amplitude-i16
                                    ;;周期の誤差をどこまで許容するかよく分からないよね
                                    (sin (* i 2pi/wavelength)))))
      (setq dst-index (+ dst-index my-snd-byte-size-i16))
      (setq i (1+ i))))
  dst-buffer)

試しに440Hzのサイン波を含むauデータを生成する関数を作る。

(defun my-snd-generate-au-sin-wave-440hz-1sec ()
  (let* ((samples-per-sec 44100)
         (seconds 1)
         (num-samples (* seconds samples-per-sec))
         (data-size (* my-snd-byte-size-i16 num-samples))
         (data (make-string (+ 24 data-size) 0)))
    ;; header
    (my-snd-aset-i32 data 0 #x2e736e64)
    (my-snd-aset-i32 data 4 24) ;;Data offset
    (my-snd-aset-i32 data 8 data-size)
    (my-snd-aset-i32 data 12 3) ;;16-bit linear PCM
    (my-snd-aset-i32 data 16 samples-per-sec)
    (my-snd-aset-i32 data 20 1) ;;Channels
    ;; data
    (my-snd-aset-sin-wave data 24 num-samples (/ samples-per-sec 440.0))

    data))

鳴らしてみましょぅ。

(play-sound (list 'sound :data (string-as-unibyte ;;string-as-unibyte必要?
                                (my-snd-generate-au-sin-wave-440hz-1sec))))

あれ、結果は (error "Invalid sound specification") だって。

おかしいなデータが壊れているのかな。試しにファイルに書き出してみる。

(with-temp-file "~/tmp/sin440.au"
  (set-buffer-file-coding-system 'no-conversion)
  (insert (string-as-unibyte (my-snd-generate-au-sin-wave-440hz-1sec))))

プレイヤーで鳴らしたら「ポー」っとちゃんと鳴ります。

それならこのファイルをplay-soundで鳴らしてみる。

(play-sound '(sound :file "~/tmp/sin440.au"))

あれ鳴らない、と思ったらプレイヤーで開いていたからでした。プレイヤーを閉じたらEmacsからちゃんと鳴りました。

play-sound関数はsubr.elにあって、Emacsのサウンドサポートを確認してからplay-sound-internal関数を呼び出しています。play-sound-internal関数はsound.cにあって、最初の方でparse_sound関数を呼び出しています。parse_sound関数を見ると……

#else /* WINDOWSNT */
  /*
    Data is not supported in Windows.  Therefore a
    File name MUST be supplied.
  */
  if (!STRINGP (attrs[SOUND_FILE]))
    {
      return 0;
    }
#endif /* WINDOWSNT */

Windowsでは :data をサポートしていないんだって！

完

そういえば昔Emacsから音を鳴らしたくて↓こういうのを作ったのでした。

• misohena/aush: Console Audio Player

これは何万個もある音声ファイルをテキストファイルと付き合わせて確認する作業で活躍したのでした。今でも動くのかは不明。